FLJoy e controller MIDI, dove sbaglio?

[codesound]

Carissimi,

Pongo un problema che ho riscontrato utilizzando il controller midi con FLjoy:

ATTENZIONE:

MIDI CC 1 = Frequenza
MIDI CC 2 = Volume

<CsoundSynthesizer>
<CsOptions>
-M3 ; ATTENZIONE!! impostare il flag corretto per il proprio setup midi...
</CsOptions>
<CsInstruments>
sr = 44100
kr = 4410
ksmps = 10
nchnls = 1
FLpanel   "XY",300,80,670,600
gkfrq, gkvol, gihLPF, gihLPvol FLjoy " ",0,5000,0,10000,0,0,-1,-1,280,60,10,10
FLpanel_end
FLrun
instr   1
kfrq ctrl7 1,1,0,5000
kvol ctrl7 1,2,0,10000
ktrig1 changed kfrq
ktrig2 changed kvol
FLsetVal ktrig1,kfrq,gihLPF
FLsetVal ktrig2,kvol,gihLPvol
a1 oscil gkvol,gkfrq,1
out a1
endin
</CsInstruments>
<CsScore>
f 1 0 4096 10 1 1
i 1 0 3600
</CsScore>
</CsoundSynthesizer>

Sebbene il principio logico funzioni correttamente, con FLjoy riscontro un fastidioso problema:
Anche se il CC 1 è la frequenza, questi modifica anche il volume e viceversa...

Dove sbaglio?

ringrazio ancora, Ruben  

[vallste]

Ho letto sulla csound mailing list (sempre sia benedetta!!!) che non si può assegnare un solo valore di FLJoy alla volta, vanno settati i due ihandle per X e Y assieme.
se cambi il tuo instr 1 così, funziona (almeno a me con la virtual keyboard di csound funziona correttamente):

instr   1
kfrq ctrl7 1,1,0,5000
kvol ctrl7 1,2,0,10000
ktrig1 changed kfrq
ktrig2 changed kvol
FLsetVal ktrig1,kfrq,gihLPF
FLsetVal ktrig1,kvol,gihLPvol
FLsetVal ktrig2,kfrq,gihLPF
FLsetVal ktrig2,kvol,gihLPvol
a1 oscil gkvol,gkfrq,1
out a1
endin

Ciao

[codesound]

Ti ringrazio vallste... funziona perfettamente!


Alla Prossima.... Rub